4.2 Le fichier linux-mailhub.rtc.mc

---8<--- COUPER ICI ----------------------------------------------------
divert(-1)
#   linux-mailhub.rtc.mc, version réseau derrière une connexion en dialup
#   Copyright (C) 2000 Thomas Nemeth.
#
#   Thanks to Jean Charles Delépine, Cyril guibourg, Erwan David, Julien
#   Blache, Yves Potin and Neil W Rickert.
#
#   This program is free software; you can redistribute it and/or modify
#   it under the terms of the GNU General Public License as published by
#   the Free Software Foundation; either version 2 of the License, or
#   (at your option) any later version.
#
#   This program is distributed in the hope that it will be useful,
#   but WITHOUT ANY WARRANTY; without even the implied warranty of
#   MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
#   GNU General Public License for more details.
#
divert(0)
include(`../m4/cf.m4')dnl Macros globales
dnl
VERSIONID(`@(#)linux-mailhub.rtc.mc, 0.3 (Nemeth) 10.08.2000')dnl
dnl
dnl ===================================================================
dnl
dnl Définition d'un OSTYPE
dnl
dnl On tournera généralement sous Linux.
dnl
OSTYPE(linux)dnl
dnl
dnl ===================================================================
dnl
dnl Utilisation des fonctionnalités génériques habituelles.
dnl
dnl le domaine 'generic' défini le nom des .forward, la feature 'redirect'
dnl et l'utilisation de sendmail.cw
dnl
DOMAIN(generic)dnl 
dnl
dnl ===================================================================
dnl
dnl Domaine générique
dnl
dnl défini la classe des domaines influencés par les genericstables
dnl utilisées plus bas. Y mettre tous les noms que votre serveur peut 
dnl prendre suivant les outils utilisés (pine, netscape, mail...) 
dnl
GENERICS_DOMAIN(mailhub.mondomaine.tld mailhub)dnl
dnl
dnl ===================================================================
dnl
dnl Ajout du nom de domaine aux mails non qualitifés
dnl pour l'émission des couriers avec user@machine.domaine.tld
dnl
FEATURE(always_add_domain)dnl
dnl
dnl ===================================================================
dnl
dnl Transformation des entêtes avec le nom du mail-hub
dnl
MASQUERADE_AS(mailhub.mondomaine.tld)dnl
dnl
dnl ===================================================================
dnl
dnl Listes des machines du réseau à relayer
dnl
dnl Noms des machines du réseau local pour lesquelles les entêtes seront
dnl ré-écrites afin que le mail-hub puisse correctement les traiter.
dnl Prévient aussi de montrer le nom de toutes les machines du réseau, mais
dnl indispensable pour l'utilisation d'un mail-hub.
dnl
MASQUERADE_DOMAIN_FILE(/etc/machines)dnl
dnl
dnl ===================================================================
dnl
dnl Listes des machines du réseau à relayer
dnl
dnl Noms des machines du réseau local pour lesquelles le relai des
dnl messages à l'extérieur sera effectué. Sans ça pas de messages
dnl vers l'extérieur à partir des autres machines du réseau.
dnl
FEATURE(`access_db',`hash -o /etc/mail/access')dnl
dnl
dnl ===================================================================
dnl
dnl Listes des machines du réseau à relayer
dnl
dnl Traiter /etc/mail/access comme une liste de machines et non comme
dnl une liste de domaines.
dnl
FEATURE(relay_hosts_only)dnl
dnl
dnl ===================================================================
dnl
dnl Ré-écriture de l'enveloppe
dnl
dnl pour que le from de l'enveloppe soit correct... nécessaire pour
dnl pouvoir contacter certains domaines bien gérés comme pasteur.fr ou 
dnl usenet.fr.net (posts dans des groupe modérés)  
dnl
FEATURE(masquerade_envelope)dnl
dnl
dnl ===================================================================
dnl
dnl Utilisation de procmail en local
dnl
dnl Par défaut le mailer local pour linux est mail.local, je lui préfère 
dnl procmail d'autant plus que mail.local n'est généralement pas
dnl fourni avec les distributions actuelles de linux. Il peut être
dnl trouvé dans le package sources de sendmail.
dnl
dnl ATTENTION, procmail est sensé être dans /usr/local/bin mais si vous ne
dnl l'avez pas compilé vous même il est certainement dans /usr/bin... 
dnl
FEATURE(local_procmail,``/usr/bin/procmail'')dnl
dnl
dnl ===================================================================
dnl
dnl Utilisation d'une table de ré-écriture de From:
dnl
dnl un FEATURE(genericstable) suffirait mais je veux rester cohérent
dnl avec la solution "Kit de Jussieu" fournie par le Guide du Rootard,
dnl je renomme donc /etc/genericstable en /etc/revaliases
dnl C'est dans ce fichier que nous définierons les règles de
dnl transcription d'adresse entre adresse locale -> adresse provider.
dnl ex: user@machine.mondomaine.tld -> ftif681124@wanadoo.fr (login@fai.fr)
dnl
FEATURE(genericstable,``hash -N /etc/revaliases'')dnl
dnl
dnl ===================================================================
dnl
dnl Ne pas cannoniser les adresses des messages à envoyer
dnl
FEATURE(nocanonify)dnl
dnl
dnl ===================================================================
dnl
dnl Définition du charset pour qu'on puisse nous lire correctement
dnl
define(`confDEF_CHAR_SET', `ISO-8859-1')dnl
dnl
dnl ===================================================================
dnl
dnl Tout ce qui coûte cher doit attendre un sendmail -q (automatique
dnl ou autoritaire)
dnl
define(`confCON_EXPENSIVE',`True')dnl
dnl
dnl ===================================================================
dnl
dnl Redirection des messages d'erreur
dnl
dnl Les messages d'erreur doivent être envoyés en copie au Postmaster
dnl
define(`confCOPY_ERRORS_TO', `Postmaster')dnl
dnl
dnl ===================================================================
dnl
dnl Pour que les messages envoyés à une liste locale soit aussi envoyés
dnl à l'auteur
dnl
define(`confME_TOO', `True')dnl
dnl
dnl ===================================================================
dnl
dnl Reconstruction automatique de la base des alias
dnl
define(`confAUTO_REBUILD', `True')dnl
dnl
dnl ===================================================================
dnl
dnl Définition des temps avant l'envoi de messages d'erreur
dnl
define(`confTO_QUEUEWARN',`12h')dnl
define(`confTO_QUEUEWARN_NORMAL',`12h')dnl
define(`confTO_QUEUEWARN_URGENT',`6h')dnl
define(`confTO_QUEUEWARN_NONURGENT',`18h')dnl
dnl
dnl ===================================================================
dnl
dnl Où doit-on envoyer les couriers externes
dnl
dnl Ce n'est pas à moi de négocier avec le bout du monde et de toute façon,
dnl n'ayant pas de DNS, je ne saurais pas le faire...
dnl On utilise smtp8 pour envoyer les accents en 8 bits sans passage
dnl par le quoted unreadable. Attention, on considère ici que
dnl mail.domaine.fr dispose d'un MTA correct acceptant les messages en 
dnl 8 bits (soit la plupart si ce n'est tout les fournisseurs d'accès)
dnl
define(`SMART_HOST', `smtp8:[smtp.fai.fr]')dnl
dnl
dnl ===================================================================
dnl
dnl Définition des drapeaux pour l'émission des couriers
dnl
dnl Le flag 'e' est là pour expensive : smtp coûte cher !
dnl Le flag 'A' est là pour aliases   : l'envoi de messages vers
dnl un utilisateur local nécessite une ré-écriture de From:
dnl Pour cela il faut des entrées dans /etc/aliases du type
dnl login@fai.fr: user
dnl IMPORTANT : Voir la doc pour les explications (4.4.1).
dnl
define(`SMTP_MAILER_FLAGS', `e')dnl
dnl
dnl ===================================================================
dnl
dnl Définition des mailers qui seront utilisés
dnl
MAILER(local)dnl
MAILER(smtp)dnl
MAILER(procmail)dnl
dnl
dnl ===================================================================
---8<--- COUPER ICI ----------------------------------------------------

Thomas Nemeth